Contenido

# Función CreateUnoService

Instantiates a Uno service with the ProcessServiceManager.

### Sintaxis:

         CreateUnoService(serviceName As String) As Object

### Devuelve tipo:

Objeto

### Parámetros:

Nombre | Tipo | Descripción
--- | --- | ---
serviceName | String | El nombre del servicio. For a list of available services, visit the com::sun::star Module reference page.

### Ejemplo:

The example below creates the function FileExists that uses the service com.sun.star.ucb.SimpleFileAccess to test if a given path is an existing file.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

UNO services have an extensive online documentation in the api.libreoffice.org website. Visit the SimpleFileAccess Service reference page to learn more about the methods provided by the service used in the example above.

### Ejemplo:

The following code uses the service com.sun.star.ui.dialogs.FilePicker to show an open file dialog:

    Sub Main
       fName = FileOpenDialog ("Seleccione un archivo")
       Print "archivo elegido: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

Temas relacionados

Función CreateUnoServiceWithArguments

Objetos, funciones y servicios de UNO

Using Calc Functions in Macros

¡Necesitamos su ayuda!